Batch file to backup and merge JeeHell Config after update

I’ve searched for an easy way to backup my \A320FMGS\ folder in front of an JeeHell Update. After each update I need to merge the existing configuration files with the files of the backup.

This little batch file is doing this now…

Requirements

• JeeHell FMGS A320
• WinMerge (https://winmerge.org)

The batch file

@echo off

rem ---------- SET DEFAULT DIRECTORIES ----------------
set pathOrg=P:\A320FMGS
set pathBkp=P:\A320FMGS - Kopie

set pathWinMerge=C:\Program Files (x86)\WinMerge\WinMergeU.exe

rem ---------- DO NOT MODIFY BELOW THIS LINE ----------
rem ---------- DO NOT MODIFY BELOW THIS LINE ----------
rem ---------- DO NOT MODIFY BELOW THIS LINE ----------


echo -----------------------------------------------------------------
echo          Backup Creation and Merge for JeeHell FMGS
echo -----------------------------------------------------------------
echo                   by Peter Rosendahl
echo             https://aviation.pero-online.de
echo.
echo.

set /p "pathOrg=Enter path to 'A320FMGS' or press ENTER for default [%pathOrg%] : "
set /p "pathBkp=Enter path to 'A320FMGS' Backup or press ENTER for default [%pathBkp%] : "

xcopy "%pathOrg%" "%pathBkp%" /e /i /y /s

set starterIni=\starter.ini
set aircraftCfg=\Aircraft\A320-214\aircraft.cfg
set aircraftIni=\FMGS Server\PERF\CFM\aircraft.ini
set egpwswxrIni=\EGPWS_WXR.ini

cls
echo -----------------------------------------------------------------
echo          Backup Creation and Merge for JeeHell FMGS
echo -----------------------------------------------------------------
echo                   by Peter Rosendahl
echo             https://aviation.pero-online.de
echo.
echo.
echo Backup done. Please make JeeHell FMGS Update and press key to continue after
echo JeeHell Update has been completed...
pause

cls
echo -----------------------------------------------------------------
echo          Backup Creation and Merge for JeeHell FMGS
echo -----------------------------------------------------------------
echo                   by Peter Rosendahl
echo             https://aviation.pero-online.de
echo.
echo.
echo Please do not close this window until all WinMerge sessions are done...
call "%pathWinMerge%" "%pathBkp%%starterIni%" "%pathOrg%%starterIni%"
call "%pathWinMerge%" "%pathBkp%%aircraftCfg%" "%pathOrg%%aircraftCfg%"
call "%pathWinMerge%" "%pathBkp%%aircraftIni%" "%pathOrg%%aircraftIni%"
call "%pathWinMerge%" "%pathBkp%%egpwswxrIni%" "%pathOrg%%egpwswxrIni%"

How it works

1. Set the path of the Original \A320FMGS folder
2. Set the path of the Backup folder (make sure that is does not exist)
3. Copy Original folder to Backup folder
4. Wait for you to complete your JeeHell FMGS Update
5. Continue the batch file opens WinMerge (external program) three times to make sure each and every config item is correct. Save the files
6. Batch file closes

Installation

1. Copy the script in a batch file (peroJeeHellBackupMerge.cmd)
2. Adjust the path settings
3. Save it in the parent folder of your A320FMGS folder
   (Example: D:\A320FMGS\ place it to D:\)